補足: 簡単なマニュアル

パッケージの利用宣言 using

using Foo とすると(インストール済みの) Foo パッケージを読み込む.

パッケージのインストール Pkg.add

using Pkg として Pkg パッケージを読み込んでから
Pkg.add("Foo") とすると Foo パッケージをインストールする.

パッケージのインストール Pkg.status

using Pkg として Pkg パッケージを読み込んでから
Pkg.status() とすると、インストール済みのパッケージのリストを表示する.

関数を定義する方法

Julia では関数を定義する方法がおおよそ 3つある.

1. 一番手堅い方法.function 命令を使う.

以下のようなものだ. 途中で計算が必要なケースなど、複雑な場合にはこの方法が適している. なお、return 命令を使うと出力値を陽に指定できる. return を使わない場合は、最後の式の結果が出力値になる.

1function f(x)
2    y = x^2
3    return x + sin(y)
4end

2. シンプルな関数向け.1行で定義する.

数学の数式で書くような方法で、たとえば 1行で次のように定義する.

1f(x) = x + sin(x^2)

3. 写像の形で表す.

写像の形を用いて表わす.名前をつけることも、つけないこともできる. 下記の例を見よう.

1plot( x -> x + sin(x^2) )  # 名前をつけない使い方の例
2
3g = x -> x + sin(x^2)      # 名前をつけて使う例
4plot(g)

上の 3つの方法のどれで定義しても Julia 内部では同じコードになるので、好きな方法を選べば良い.

ブロードキャスト, ドット作用素

ブロードキャスト

A型変数の要素をもつ配列 v があり、 A型変数を入力できる関数 f() があるとする.
そして、 v の要素ぞれぞれに f() を作用させたい場合は f.(v) と書くだけで良い、というのがブロードキャストである. 下記の例を見よう.

1v = [1, 2, 3]
2sin.(v)

とすると、下記を得る.

3-element Vector{Float64}:
 0.8414709848078965
 0.9092974268256817
 0.1411200080598672

ドット作用素

二項演算子等では、ブロードキャストを簡略した、直感的な表記が使える. たとえば、複数の要素を持つ対象 v の要素それぞれに、スカラー関数である「三乗」を作用させたい場合、 べき乗記号の ^ に ドット . をくっつけて .^ として v .^ 2 とすればよい. 下記の例を見よう.

1[1, 2, 3] .^ 3

とすると

3-element Vector{Int64}:
  1
  8
 27

となる.

ギリシャ文字(α, β, π など)の入力方法

Julia の REPL環境や Jupyter環境では、上の公式マニュアルに載っている "\" で始まる入力をしてから Tab キーを押すと、その字体に変換できる. 例えば、

  • \alpha → α
  • \beta → β
  • \gamma → γ
  • \pi → π

といった具合だ.

range, 範囲

数字の「範囲」を記述する. 数字が並んだ数列ではないので、メモリを大変節約でき、高速だ.

  1. a から c まで.ただしステップサイズ = 1 で.

    1v = a:c        # 糖衣構文(Syntax Sugar). 便利.
    2v = range(a,c) # 正式な文法
    
  2. a から c まで.ただしステップサイズ = b で.

    1v = a:b:c                # 糖衣構文(Syntax Sugar). 便利.
    2v = range(a,c, step = b) # 正式な文法
    
  3. a から c まで.ただし全部で n個.

    1v = range(a,c, length = b) # 正式な文法
    
  4. その他. マニュアルを読もう.

データ集合の取り扱い

データを集めて集合として扱う場合、集合を作ったり、要素を足したり、要素を削除したり… 等の処理が必要だ.それには上記の公式マニュアルを読むと良い.簡単なものだけでも下記に記載しておこう.

  • 集合を作って名前をつける
 1v = [2, 5, -9] 
 2# [] の中に要素を並べて配列を作れる.配列の要素はすべて「同じ型」でないといけない.
 3# 上の例は要素が「整数型」で揃っている.
 4
 5M = [1 2 3
 6     4 5 6
 7     7 8 10]
 8# 2次元的に並べると行列(2次元配列)も作れる.
 9
10w = (2, "a", 0.1)
11# () の中に要素を並べてタプルという集合を作れる.タプルの要素は「違う型」でも良い.
12# この自由度の高さの代わりにタプルは処理も遅く、線形代数計算も使えない.
  • 集合に要素を付け足す

上の例に続けて下記のようにすると

1push!(v, 3)

配列 v に要素 3 が付け加えられて

4-element Vector{Int64}:
  2
  5
 -9
  3

となる.

  • 集合から要素を取り出す

上の例に続けて下記のようにすると

1pop!(v)

配列 v の最後の要素が取り出されて 3 と表示され、v自身は

3-element Vector{Int64}:
  2
  5
 -9

に戻る.さらにもう一度 pop!(v) をすると最後の要素 -9 が取り出されて表示され、v自身は

2-element Vector{Int64}:
  2
  5

になる.

などを参照しよう.

  • 行列などの多次元配列から特定の次元の情報を取り出す(slicing, indexing)

    詳しくは マニュアル を読むしか無いが、例をいくつか示しておく.

    1M = [  1.0   0.5    0.35    0.333537   0.333333
    2      -1.0  -0.75  -0.675  -0.666768  -0.666667 ]
    

    に対して、行列 $M$ の要素 $m_{i,j}$ のうち $m_{1,j}$ のみを取り出すには

    1M[1, :]
    

    とすれば良い.実際、

    5-element Vector{Float64}:
     1.0
     0.5
     0.35
     0.333537
     0.333333
    

    という出力を得る.

    同様に、行列 $M$ の要素 $m_{i,j}$ のうち $m_{i,3}$ のみを取り出すには

    1M[:, 3]
    

    とすれば良い.実際、

    2-element Vector{Float64}:
      0.35
     -0.675
    

    という出力を得る.

ループから配列を作る (内包表記)

[ 式 for 変数 in 範囲 ] とすると、変数をその範囲でループさせて式を計算し、それを並べて配列にする. プログラムを書いて要素を一つずつ追加するよりも高速に動作するのでおすすめ.

下記に例をあげる.

1v = [ 1/n^2 for n in 1:10 ]
10-element Vector{Float64}:
 1.0
 0.25
 0.1111111111111111
 0.0625
 0.04
 0.027777777777777776
 0.02040816326530612
 0.015625
 0.012345679012345678
 0.01

yes/no 判定で動作を変える: if文

公式マニュアル if文

yes/no 判定をして動作を変える if というコマンドがある. これは下記の例を見るのが早いだろう.

1if x < y
2    println("x is less than y")
3elseif x > y
4    println("x is greater than y")
5else
6    println("x is equal to y")
7end

繰り返す: for文

公式マニュアル 繰り返し for文

変数が「範囲」や集合の要素を一つずつ取り出してその値をとるときのループ処理を記述するのが for 文. 下記の例を見よう.

1for x in [1, 4, -2]
2  println(x)
3end
1
4
-2

データの代表的な情報を得る

データの情報は、おおよそ次のどちらかのマニュアルから探せるだろう.

  1. 公式マニュアル 集合に関して collections
  2. 公式マニュアル 配列に関して arrays

線形代数

公式マニュアル Linear Algebra

線形代数については流石に分量が多すぎるので、基本的には上のマニュアルを参照してもらおう. なお、ほんの少しだけ記載する.

多倍長計算

公式マニュアル BigFloat BitInt

数字を多倍長で扱いたい場合、 普通の数字には BigFloat 型を、整数型には BitInt 型を使うと良い.

  1. BitInt の例

    1n = 10
    2n1 = BigInt(n)
    

    たとえば、この状況で n^19 を計算すると -8446744073709551616というおかしな値になる が、n1^19 とするときちんと 10000000000000000000 が得られる.

  2. BitFloat の例

     1x = 2.1
     2x1 = BigFloat(x)
     32.100000000000000088817841970012523233890533447265625
     4# 既に Float64 として扱われてしまっている数字を変換. もとの誤差が乗ってしまう.
     5
     6x2 = BigFloat("2.1")
     72.09999999999999999999999999999999999999999999999999
     89999999999999999999999999986
     9 # 2.1 に最も近い多倍長数として入力する. お勧め.
    10
    11x3 = BigFloat("2.1", precision=128) 
    122.100000000000000000000000000000000000007
    13# 精度(デフォルトは 256bit)を指定したい場合.これは 128bit に設定している.
    14# 通常の Float64 は 64bit.
    

    たとえば、この状況で x^1000 を計算すると計算が Float64 の値の外へ出てしまい Inf となってしまって計算値が得られないが、 x2^1000 とすると

     1.656894033019239458966306694065293835477820492667187694129435723243661071403152e+322
    

    となり、問題なく結果が得られる.

Plots package: plot: 描画範囲

公式マニュアル Plots: Basic Concepts
公式マニュアル Plots: Useful Tips

グラフの描画範囲は自分で決められる.いくつか方法がある. 例えば x軸の範囲を決める方法を下記に示すので好きなものを使おう.

1plot(sin, -π, π)         # 描画範囲の左右端を直接指定
2plot(sin, -π:0.1:π)      # 描画範囲を「範囲」で指定.
3plot(sin, xlims=(-π,π))  # 描画範囲を制限する.複数のグラフを揃えるときなどに.

Plots package: plot: マーカー形状

公式マニュアル Plots: Marker Types

1using Plots
2Plots.supported_markers()

とするとマーカータイプのリストを得られる. 実際の形状は

1using Plots
2markers = filter((m->begin
3                m in Plots.supported_markers()
4            end), Plots._shape_keys)
5markers = permutedims(markers)
6n = length(markers)
7x = (range(0, stop = 10, length = n + 2))[2:end - 1]
8y = repeat(reshape(reverse(x), 1, :), n, 1)
9scatter(x, y, m = markers, markersize = 8, lab = map(string, markers), bg = :linen, xlim = (0, 10), ylim = (0, 10))

とすると見られる.その結果は以下の通り.

Plots package: plot: 対数グラフ

公式マニュアル Plots: Logarighmic scale plots

対数グラフを描くのは簡単だ.下記のように、対数スケールにしたい軸に対して plot のオプションを設定すれば良い.

まずは通常のグラフ

1X = 0.01:0.01:10
2f(x) = x^2 + x + 1
3
4using Plots
5default( xlabel = "x", ylabel = "x^2+x+1", legend = false )
6plot(f, X)

y軸を log_10 でスケールする例

上と同じ状況で下記のように yaxis オプションに :log10 を設定すると良い. x軸の場合は xaxis = で設定すれば良い.

1plot(f, X, yaxis = :log10 )

:log10 以外の軸のスケール表示

全部で下記のようなスケールがある. この情報は、例えば Julia で plotattr("scale") とすると知ることができる.

  • :identity ← そのまま、という意味.
  • :ln ← 自然対数
  • :log2 ← 底を 2 にとった対数
  • :log10 ← 底を 10 にとった対数
  • :asinh ← 逆双曲線正弦. ただし実装されていないために使えないことが多い.
  • :sqrt ← 1/2乗.これも実装されていないために使えないことが多い.

Plots package: plot: オプションのデフォルト設定

公式マニュアル Plots: default

Plots package の利用時に、default(オプション設定) とすると、そのオプション設定がそのセッション中ずっと有効になる. たとえば、

1default( xlabel = "x" )

とすると、それ以降は設定しなくてもすべてのグラフに xlabel = "x" と設定したことになる.

Plots package: plot!: plot にあとから「追加」

公式マニュアル Plots: plot このマニュアルの項の1行目に

"Use plot to create a new plot object, and plot! to add to an existing one"

と書いてあるように、最後に plot で作ったグラフにいろいろ追加できるコマンドが plot! である. 下記の例を見よう.

オプションを追加する

1using Plots
2plot(sin)
1plot!(xlabel = "x") # x軸ラベルを追加設定.

グラフの重ね描きにも使える.

例えば上の例に続けて

1plot!(cos) # cos のグラフを追加

とすると、次のようなグラフを得る.

エラーメッセージの読み方

エラーについて、ごく簡単な分類の解説が上のリンク先にある.

さらに、エラーメッセージそのものの「読み方」について例を示そう. 例えば、負の数のべき乗計算である (-1.0)^(1.2) を行おうとすると、(jupyter 上では)

DomainError with -1.0:
Exponentiation yielding a complex result requires a complex argument.
Replace x^y with (x+0im)^y, Complex(x)^y, or similar.

Stacktrace:
 [1] throw_exp_domainerror(x::Float64)
   @ Base.Math .\math.jl:41
 [2] ^(x::Float64, y::Float64)
   @ Base.Math .\math.jl:1155
 [3] top-level scope
   @ In[97]:1
 [4] eval(m::Module, e::Any)
   @ Core .\boot.jl:489

というようにエラーメッセージが出力される.このエラーメッセージの読み方だが、

  1. 最初に,Stacktrace という部分を探す. ここには,エラーが起きた箇所から始まって,その動作を呼出した場所へと逆上っての情報が記されている.

  2. 次に、Stacktrace 中の top-level scope という文字列を探す. top-level scope というのはプログラムを動かしている一番表面部分になる.つまりプログラムコードそのものだ.

    上記の場合、そこに

     [3] top-level scope
       @ In[97]:1
    

    とある.この @ 以降を読む. これが,このプログラムのエラー箇所の「一番表面的な箇所」になる.

    この場合 In[97]:1 となっているが, In[97] は jupyter の入力の [97]: という箇所1を意味し,そして最後の :1 はその 1行目だ,ということを表している.

  3. 次に,stacktrace を一つずつ上へ向かって読み進めて状況を把握していく. この場合,

     [2] ^(x::Float64, y::Float64)
       @ Base.Math .\math.jl:1155
    

    となっており、^ という計算、つまり 1.2乗の計算でエラーになったということを示している.

  4. さらに stacktrace を上へ向かい,

     [1] throw_exp_domainerror(x::Float64)
       @ Base.Math .\math.jl:41
    

    とあり,「exp_domainerror (範囲外エラー)というエラーで2,処理をした」と言っている. なお,エラーの発生箇所にたどり着いたので stacktrace の追いかけはここで終了だ.

  5. この最終的なエラーについては出力されたエラーメッセージ中に解説が書いてあるのでそれを読めば良い. そこで出力されたエラーメッセージの内容、すなわち、 DomainError with -1.0: で始まる 3行のエラー説明部分を読んでみると,

     DomainError with -1.0:
     Exponentiation yielding a complex result requires a complex argument.
     Replace x^y with (x+0im)^y, Complex(x)^y, or similar.
    
     意訳: -1.0 で「範囲外エラー」になった.
      結果が複素数になる指数計算は引数が複素数であるべき.
      (複素計算であるならば) x^y を (x+0im)^y か Complex(x)^y といった表記に直せ.
    

    と言っている.

    つまり、(-1.0)^1.2 の ^1.2 の計算にあたり数字が「範囲外」エラーだ,と言っているので、 ^1.2 の引数の (-1.0) の値が仕様外だと言っていることになる.

    このように読んでいけば、エラーメッセージによってエラーの発生場所とその意味が読み取れるだろう.


  1. これは教員が動かしたとき,In [97] にこのプログラムを書き込んだからだ. ↩︎

  2. 一応,domainerror についてはマニュアルの Core.DomainError に解説があり,
        The argument val to a function or constructor is outside the valid domain.
    と書いてある.わかりやすい例も載っている.見ておくと良いね. ↩︎