05. 常微分方程式: モデリングと Euler法
Photo by Roman Mager on Unsplash
今回から、常微分方程式の数値計算を扱う
人類が世界を理解し、制御するためによく使う数学的技術の一つが微分方程式である. 今回から、その微分方程式の一番シンプルな形式である常微分方程式について、数値計算を用いて解を求める技術等を学ぼう.
モデリングとは
モデリングに関する、わかりやすい古典的な題材を資料
- モデリング古典3題 (pdf)
で紹介するので、これで学ぼう.
単純な常微分方程式を Euler 法で計算してみよう
対象の微分方程式
対象として, 上の資料に載っている人口問題を考える. そしてここでは,$u = u(t)$ ($t$: 時間) に対する常微分方程式 \begin{equation} \frac{du}{dt} = \gamma\, \left( \sin(u) \right)^{1.2}, \,\, \gamma > 0, t \in (0,\infty) \end{equation} をモデルとする仮説をたてた,としよう. ただし、$u$ の初期値 $u(0)$ については $0 < u(0) < 1$ としておく.
近似計算式を作る「Euler 法」
早速,このモデルのシミュレーション(つまり数値計算)を試みたい. そのための Euler 法と呼ばれるシンプルな考え方を紹介しよう.
まず,時間刻み幅 $\Delta t$ を一定にして、解 $u(n\Delta t)$ の近似値を $u_n$ と表記することにしよう. 次に、モデル方程式中の $u(t)$ やその微分を、$u_n$ を用いて近似して近似計算式を作ることを考える. この近似の際に、
微分の近似は陽的差分 $(u_{n+1} - u_n)/\Delta t$で行い、未知量 $u_{n+1}$ を使う.しかし、それ以外の部分には既知値 $u_n$ だけを使う.
として近似計算式を作る方法が Euler法 と呼ばれる方法だ. これからの例でわかるが、こうして得られた近似計算式は便利な形になっていることが多いのだ.
実際、今回の対象としている微分方程式に Euler 法を適用してみると、
\begin{equation} \frac{u_{n+1} - u_n}{\Delta t} = \gamma\, \left( \sin(u_n)\right)^{1.2} \end{equation}
となる. 左辺に新しい値による項を集め,右辺に古い値による項を集める形で整理するとさらにわかりやすく
\begin{equation} u_{n+1} = u_n + \Delta t \,\, \gamma \,\, \left( \sin(u_n)\right)^{1.2} \label{eq:euler-scheme} \end{equation}
となり、
既知の量 $u_n$ から未知量 $u_{n+1}$ が直接計算できる = 時間発展が直接計算できる
形になっていることが明確になる. このように、既知量を代入すると未知量が計算できる形の式を「陽な形」などと呼ぶ.
このように、Euler法によって陽な近似式を導出できたので、既知な初期値 $u_0 = u(0)$ からそれ以降の近似値を $u_1, u_2, \cdots$ と順番に求めていける.
プログラミング: まず各種定数などを定義
とりあえず下記のように定数を設定しておこう.
1# 問題に含まれる定数
2γ = 1.0
3
4# 初期値
5u0 = 0.1
6
7# 数値スキームのパラメータ
8Δt = 0.1 # 特に根拠のない,とりあえずの値だ.
Euler スキームを関数として定義しよう
次に、Euler方による近似式 ($\ref{eq:euler-scheme}$)、これを Eulerスキームなどと呼ぶ、もプログラミングしよう. 下記のようにすればよいだろう.
1Euler(u) = u + Δt * γ * (sin(u))^1.2 # 入力:古い近似値, 出力:新しい近似値
定義した Euler スキームを使って、初期値から順番に近似値を計算しよう
あとは順番に計算していけばいいだけだ.下記のようになるだろう.
1u = u0 # 初期値を値として設定.
2u_sq = [ u ] # 結果を配列に貯めていく.
3
4for n in 0:99 # 最初は第0ステップ相当.とりあえず u_100 まで試してみよう.
5 u = Euler(u) # Euler スキーム: 古い u -> 新しい u
6 push!(u_sq, u) # push! で配列に要素を追加する.
7end
結果のグラフを見てみよう
上の計算が終わると、配列 u_sq に $u_0, u_1, \cdots, u_{100}$ の要素が入っているはずである. そこでこの数列をプロットしてみよう.
いつものように Plots パッケージを用いて下記のような感じだ.
1using Plots
2
3T = 0:Δt:100Δt
4plot( T, u_sq, marker = :circle, xlabel = "t_n", ylabel = "u_n", legend = false)
おめでとう! 君はおそらく初めての自力でのシミュレーションに成功した!
仮説を数値で検証するスキルを手に入れたのだ.
さて,この場合グラフからも想像できるように,
$u(t)$ が下から $\pi$ に近づいていく. 数式をみて納得しておこう.
そこで、グラフに $\pi$ の値を示す水平線も追加しておこう.以下のような感じだ.
1plot( T, u_sq, marker = :circle, xlabel = "t_n", ylabel = "u_n", legend = false)
2hline!([π], linewidth = 3 )
Euler法は失敗しやすい.体験してみよう.
Euler 法は数式の変形も簡単だし、プログラムも簡単だ.実行速度も速い. しかしその分,(まだ説明していないが)結果の精度は悪いし、計算過程は不安定だ. ここでいう不安定というのは、数値解が発散したりすることを言う.
このことを、実際に見てみよう.やり方は簡単で、時間発展を追いかける際の $\Delta t$ を少し大きめにするだけでいい…
1Δt = 1.2 # 以前はこの値が 0.1 だった.少し欲張って大きくしてみる.
さて、さきほどと全く同じように計算してみよう.ただし、過程がわかりやすいように、途中結果をいちいち表示させよう.
1u = u0 # 初期値を値として設定.
2u_sq2 = [ u ] # 結果を配列に貯めていく.
3
4for n in 0:99 # 最初は第0ステップ相当.とりあえず u_100 まで試してみよう.
5 println(n,": ",u,": ",sin(u)) # 途中経過を画面に出す.
6 u = Euler(u) # Euler スキーム: 古い u -> 新しい u
7 push!(u_sq2, u) # push! で配列に要素を追加する.
8end
すると、途中までは下記のような出力を出してくれるが、
0: 0.1: 0.09983341664682815
1: 0.17556355249608085: 0.17466305501555435
2: 0.3234139541098293: 0.3178053673300265
3: 0.6266457368366771: 0.5864311118638564
4: 1.2591182402790926: 0.9518203144684844
5: 2.390078148041807: 0.6827461247045289
6: 3.149166519606018: -0.007573793605922763
このあと下記のようなエラーメッセージを出力してプログラムは停止してしまう.
DomainError with -0.007573793605922763:
Exponentiation yielding a complex result requires a complex argument.
Replace x^y with (x+0im)^y, Complex(x)^y, or similar.
Stacktrace:
[1] throw_exp_domainerror(x::Float64)
@ Base.Math .\math.jl:41
[2] ^
@ .\math.jl:1155 [inlined]
[3] Euler(u::Float64)
@ Main .\In[19]:1
[4] top-level scope
@ In[29]:6
[5] eval(m::Module, e::Any)
@ Core .\boot.jl:489
エラーを示して停まってしまった.何が起きた? まずはエラーの調査だ
エラーが起きて停まった. プログラムを書いて動かす場面ではエラーはよく出てくるものであるから,これと付き合えないと話が進まない.
今回はせっかくなので,エラーメッセージの読み方を知って,状況を把握できるようになっておこう.
最初に,上のエラーメッセージの Stacktrace という部分を見よう. ここには,エラーが起きた箇所から始まって,その動作を呼出した場所へと逆上っての情報が記されている.
真面目にいくならば,[1] から順に読んでいって,まずは top-level scope という文字が出てくる箇所を探そう. top-level scope というのはプログラムを動かしている一番表面ということで, この場合は jupyter に書き込んだプログラムそのものなのだ.
実際,この場合,
[4] top-level scope
@ In[29]:6
というものが見つかる.
そしてこの @ 以降を読む.
これが,このプログラムのエラー箇所の「一番表面的な箇所」になる.
この場合 In[29]:6 となっていて, In[29] は jupyter の入力の [29]: という箇所1だ,ということを意味し,そして最後の :6 はその 6行目だ,ということを表している.
実際,上の入力の 6行目をみると u = Euler(u) となっているので,自分で定義した関数 Euler でエラーが出た,ということがわかる.
次に,この場所から stacktrace を上へ向かって読み進めて状況を細かく把握していく. この場合,
[3] Euler(u::Float64)
@ Main .\In[19]:1
となっていて,関数 Euler を定義した際の 1行目,つまり return u + Δt * γ * (sin(u))^1.2 でエラーになったということがわかる.
次にさらに stacktrace を上へ向かい,
[2] ^
@ .\math.jl:1155 [inlined]
を見る.
これはエラーの起きた行の ^ という箇所,つまり,sin(u)^1.2 の "^" の箇所、つまり 1.2乗の計算でエラーになったということを言っている.
さらに stacktrace を上に行くと
[1] throw_exp_domainerror(x::Float64)
@ Base.Math .\math.jl:41
とあり,「exp_domainerror というエラーで2,処理をした」と言っている. なお,エラーの発生箇所にたどり着いたので stacktrace の追いかけはここで終了だ.
そしてこの最終的なエラーについては出力されたエラーメッセージ中に解説が書いてあるのでそれを読めば良い.
そこで出力されたエラーメッセージの内容を読むと、
DomainError with -0.007573793605922763: で始まる 3行のエラー説明部分である.
読んでみると,
DomainError with -0.007573793605922763:
Exponentiation yielding a complex result requires a complex argument.
Replace x^y with (x+0im)^y, Complex(x)^y, or similar.
意訳: -0.007573793605922763 で「範囲外エラー」になった.
結果が複素数になる指数計算は引数が複素数であるべき.
(複素計算であるならば) x^y を (x+0im)^y か Complex(x)^y といった表記に直せ.
と言っている.
つまり、sin(u)^1.2 の ^1.2 の計算にあたり数字が「範囲外」エラーだ,と言っているので、
^1.2 の引数の sin(u) の値が仕様外だと言っていることになる.
具体的には
sin(u)が負の値になり,エラーの原因になったのでは?
と推測できる.
これは ^1.2 という計算がどうやって行われるかを考えればわかる. $x^{1.2} = ( e^{\log(x)} )^{1.2} = e^{1.2\log(x)}$ として計算されるので,計算 $\log(x)$ ができないときはエラーになる. そしてそれは $x \leq 0$ のときで,これが今回の推測となる.
実際,プログラムが出力した直前の表示
6: 3.149166519606018: -0.007573793605922763
の右端の数字は sin(u)の値だが、これが確かにマイナスになっている.
しかもこの数字 -0.007573793605922763 はエラーメッセージにも現れている.
よって、エラーは
1(-0.007573793605922763)^1.2
を計算しようとして出たものと考えてよいはずだ.
確認のため,実際に上の1行計算を実行させてみよう.そうすると、
DomainError with -0.007573793605922763:
Exponentiation yielding a complex result requires a complex argument.
Replace x^y with (x+0im)^y, Complex(x)^y, or similar.
Stacktrace:
…略…
と出力され,先のものと全く同じエラーメッセージが現れ、この推測が正しかったことがわかる.
次に、自分の意図とプログラム動作のズレを把握しよう
さて、エラーの原因が sin の値がマイナスになったことだとはっきりとわかったので、
次に,なぜマイナスになったのか,数字を丁寧に追いかけてみよう.
そんなことが起きるつもりではなかったのだから.
まず、7回目の出力 6:... を見るとわかるように、$u$ が $\pi$ をわずかに超えている. しかしそもそもこの初期値からの時間発展では解は $\pi$ 未満にとどまるはずで、これはあり得ない現象だ.
つまり、Euler 法の誤差によって近似解が $\pi$ 以上になり、そのために sin(u) が負になってしまったということだ.
では、その「誤差による影響」がどのように近似解に現れたのか、plot を使って確かめよう.
まず,$\Delta t$ が小さいときと大きいときの結果がどう違うのか.同時にグラフを表示してみよう. まず、近似解の値そのものを比べてみよう.
1default( xlabel = "t_n", ylabel = "u_n" )
2
3T2 = [ n * 1.2 for n in 0:6 ] # plot にわたすのは範囲でなくて配列でも良い.
4plot(T2, u_sq2, marker = :circle, label = "Dt = 1.2") # Δt = 1.2 の方
5
6T1 = [ n * 0.1 for n in 0:72 ] # エラーで止まった方に合わせて最初の70点ほどに
7plot!(T1, u_sq[1:73], marker = :rect, label = "Dt = 0.1") # Δt = 0.1 の方
8
9hline!([π], lw = 3, label = "upper limit" )
ふむ、見ると分かるが、「失敗したほう, つまり粗い方」は解が大きくなっていくスピードにブレーキがかかるのが遅れるために 突破するはずのない値 $\pi$ を近似解が突破してしまう、という格好だ.
この「真の解よりも近似解の挙動が必ず遅れる」ことは Euler法の特徴と言ってよく、今回はこれが強くでてしまった、ということだ.
これでエラーの正体が理解できた、と言ってよいだろう.
Δt の値をどうすれば安全にプログラムが動くのか?
ならば Δt はいくつにするべきなのか? 実はこれは「数値安定性を確保するためのパラメータの決定」という問題で,一般には結構難しい.
ただ今回はスキームが大変シンプルなので,結構簡単に調べがつく.やってみよう.
まず,Eulerスキームの計算が直前までうまくいっている、つまり,$u_n < \pi$、という状況下で今回のエラーを回避するための条件は以下のように書ける.
\begin{equation} u_{n+1} < \pi . \end{equation}
これを今回の Euler スキーム $\eqref{eq:euler-scheme}$ の場合について書き直すと、
\begin{equation} u_n + \Delta t \,\, \gamma \,\, \left( \sin(u_n)\right)^{1.2} < \pi \end{equation}
となるので,これを $\Delta t$ についての式に変形すると
\begin{equation} \Delta t < \frac{\pi - u_n}{\gamma\,\, \sin(u_n)^{1.2}} \end{equation}
となる.
よって,この右辺の最小値を調べ,(その値が正ならば) $Δt$ をその値より小さくしておけば安全,と言える.
そこでこの右辺を \begin{equation} Up(u) = \frac{\pi - u}{\gamma\,\,\sin(u)^{1.2}} \label{up:up-u} \end{equation} と定義して,まずはこのグラフを描いてみよう.
1Up(u) = (π - u )/ ( γ * sin(u)^(1.2) )
2
3plot( 0:0.01:π, Up ) # u_n の範囲は 0 より大きく π より小さいので.
グラフは左端が一番大きく,よーく見ると右端も少し上がっている. そこでもう少しわかりやすいように範囲を狭めてグラフを描いてみよう.
1plot( 1.0:0.01:π, Up )
このグラフに依ると $u$ が 2.4 の付近? に最小値があるように見受けられる. 実際,真面目に最小値を満たす $u$ を求めると3
\begin{equation} u_{\mbox{min}} = 2.446142705263389 \label{eq:u-min} \end{equation}
と求められ,そしてそのときの $Up(u)$ の値は
\begin{equation} Up(u_{\mbox{min}}) = 1.1864652653081016 \end{equation}
となる.つまり,
\begin{equation} \Delta t < 1.1864652653081016 \end{equation}
ならば今回のエラーを起こさずに計算が可能だ,ということになる.
実際,Δt = 1.186465 として計算しても確かに計算がうまくいくことなどが実際に確認できる.やってみよう.
Euler法の精度(誤差)を測る
Euler法は近似解法であり、その精度(誤差)は常に気にしたい. そこで、それを測ってみよう.
memo: 事前準備としての高精度計算
誤差の挙動を見るために、可能ならば「真値にかなり近い値」を用意しておきたい. 今回は下記のようにしてみる.プログラムの内容は理解しなくて良い.
1using OrdinaryDiffEqVerner # 手軽に高精度計算をする際にオススメなライブラリらしい.
2
3# 以降、念の為に多倍長計算にしておく.
4g(u, params, t) = (sin(u))^(BigFloat("1.2"))
5prob_g = ODEProblem(g, BigFloat("0.1"), ( BigFloat("0.0"), BigFloat("10.0") ))
6
7sol = solve(prob_g, OrdinaryDiffEqVerner.Vern9();
8 reltol=1e-30, abstol=1e-32) # 30桁ほどの精度を要求
9
10sol( BigFloat("10.0") ) # t = 10.0 における近似値
3.11842131965310391697700226991073569407530921075054475844010833123323252093513
となるので、通常の浮動小数点数に合わせて上から17桁を取得して(最後は四捨五入) \begin{equation} u_{\text{approx}}(t=10) := 3.118421319653103917 \end{equation} を真値 $u(10.0)$ に近い値として、以降では誤差の推定に役立てることとしよう.
準備: 最終時刻までの計算をする関数
準備として、初期値と計算回数, そして最終時刻を入力すると最後の解を出力する形で関数を作ろう.以下のような感じだ.
1
2Euler(u, dt) = u + dt * γ * (sin(u))^1.2
3# 刻み幅も明示するように Euler という関数に別定義を与えておいて…
4
5function Euler_all(init_u, N, T) # N: 計算回数、T: 最終時刻
6 u = init_u # 最初の値
7 dt = T/N
8 for n in 1:N
9 u = Euler(u, dt) # Euler スキームで新しい値を求める.
10 end
11 return u
12end
念のために、きちんと動くことを確認しよう.
1Euler_all( u0, 100, 10.0 )
3.119420135870497
ふむ、大丈夫そうだ.
近似解法のパラメータと誤差の関係を評価してみる
ここでは近似解と上の値との違いを誤差とみなして、それが Euler法のパラメータである $\Delta t$ とどう関係するか、評価してみよう.
具体的には,異なる値の $\Delta t$ に対する誤差をグラフにプロットして様子を見るのだ. これで何か見えてくるだろう.
まず,様々な $\Delta t$ に対して計算して $t = 10$ のときの誤差がどうなるのか,記録を取ろう. 少し長いが,下記のようなプログラムになるだろう.
1# 全体条件
2T = 10.0 # この時間の…
3u_exact = 3.118421319653103917 # 厳密解もどき.
4
5ratio = 1.5 # 計算回数を毎回 1.5倍する <=> Δt を毎回 2/3 に.
6N_iter = 15 # この試行を何回やるか.
7
8# 初期化
9N = 100
10Δt = T/N
11u0 = 0.1
12
13# 最初に一回計算しておく.
14e_euler = Euler_all(u0,N,T) - u_exact
15
16println("iter, N, Δt, e_euler") # 画面表示
17println("0, $N, $Δt, $e_euler")
18
19# 記録をとりはじめる.
20sq_dt = [ Δt ]
21sq_euler = [ e_euler ]
22
23# Δt を小さくしていったときの近似解をそれぞれ求める.
24for i in 1:N_iter
25 N = round(Int, ratio * N) # N を ratio 倍して,
26 Δt = T / N # Δt は 1/ratio 倍になるはず.
27 push!( sq_dt, Δt ) # 記録をとる
28
29 e_euler = Euler_all(u0, N, T) - u_exact # 誤差を評価
30 push!(sq_euler, e_euler) # 記録をとる
31
32 println("$i, $N, $Δt, $e_euler") # 画面表示
33end
すると次のような結果が得られる.
iter, N, Δt, e_euler
0, 100, 0.1, 0.0009988162173928394
1, 150, 0.06666666666666667, 0.0006564740322168028
2, 225, 0.044444444444444446, 0.0004334550057136788
3, 338, 0.029585798816568046, 0.00028667096316636886
4, 507, 0.01972386587771203, 0.00019028442773283416
5, 760, 0.013157894736842105, 0.0001265708703006574
6, 1140, 0.008771929824561403, 8.421618376264206e-5
7, 1710, 0.005847953216374269, 5.607101880888976e-5
8, 2565, 0.003898635477582846, 3.73481771540618e-5
9, 3848, 0.002598752598752599, 2.4881098820817016e-5
10, 5772, 0.0017325017325017325, 1.6580978176250483e-5
11, 8658, 0.001155001155001155, 1.1051131353578825e-5
12, 12987, 0.00077000077000077, 7.3661523334322965e-6
13, 19480, 0.000513347022587269, 4.910330441809663e-6
14, 29220, 0.00034223134839151266, 3.2733030206344438e-6
15, 43830, 0.00022815423226100844, 2.1820906175307186e-6
状況を把握するために,グラフにしてみよう.
1default( xaxis = ("Δt", :log10), yaxis = ("error", :log10) )
2
3plot(sq_dt, abs.(sq_euler), marker = :circle, label = "via Euler scheme")
4
5# グラフを見やすくする為の補助線を y = Cx という一次式で描いてみる
6default(marker = :none)
7plot!(sq_dt, 2.0e-2 .*(sq_dt), marker = :none, label = "y = Cx")
この両対数グラフでのグラフの傾きは 1 である(目盛りで見てみよう)し,$y = Cx$ として引いた補助線とも同じ挙動であるので、
Euler 法では $\Delta t$ と誤差は比例する ことがわかる4.
Euler 法の計算速度も測りたい
Euler 法のパラメータ $\Delta t$ と計算時間との関係も測ってみよう.
Julia でプログラムの計算時間を測る方法は 5つ以上あるが、他のプログラムの影響等をなるべく排除して測定したいという場合は、複数回測定して統計的に測れる BenchmarkTools パッケージの @benchmark というマクロを使うと良い.今回はこれを用いよう.
BenchmarkTools インストール
この package は自分でインストールする必要がある.以下のようにする.一回だけやれば良い.
1using Pkg
2Pkg.add("BenchmarkTools")
BenchmarkTools を使って計算時間などを測定する(目視)
さて,早速だがこのマクロを使って計算速度を測定、比較してみよう. まずパッケージの利用宣言を以下のようにして、
1using BenchmarkTools
あとは測定したい関数を @benchmark マクロに以下のように渡すだけだ.
1@benchmark Euler_all(u0, 100, 10.0)
すると,次のように計算時間に関する簡単な統計情報を教えてくれる. 計算時間を「目視」したい場合はこれで十分だ.
BenchmarkTools.Trial: 10000 samples with 5 evaluations per sample.
Range (min … max): 6.600 μs … 510.560 μs ┊ GC (min … max): 0.00% … 0.00%
Time (median): 7.520 μs ┊ GC (median): 0.00%
Time (mean ± σ): 12.606 μs ± 14.698 μs ┊ GC (mean ± σ): 3.97% ± 5.40%
█▅▄▃▂▁▂▆▂▁▁▁▁ ▁ ▁ ▂
████████████████▇▇█▆▇▅█▅▆▅▅▅▅▃▅▅▆▅▄▅▄▅▃▄▄▅▄▆▃▄▄▄▃▃▃▄▃▄▆▃▁▁▃▄ █
6.6 μs Histogram: log(frequency) by time 86.3 μs <
Memory estimate: 10.95 KiB, allocs estimate: 701.
結果を見ると、10000回のサンプルで, 平均が 12.6 μsぐらいの計算時間だということや,その他諸々がわかる. 真ん中のグラフは計算時間の頻度グラフだ. 実質的にはまあ運悪く遅い場合でも 28 μs ほどで済みそうだということなども読み取れる.
Benchmark 結果の中の GC は garbage collection (ゴミ処理) の頭文字で,使わなくなったメモリの整理等の作業を意味している. 真の計算時間ではないが、ユーザからの見た目では計算時間に入る. 状況によっては GC が見た目の計算時間の 99%以上を食ってしまうケースが有り,GC が発生するとかなり時間を食う. PC で使えるメモリが少ないほど GC が頻繁に発生するので,メモリが少ないとつらいね.
BenchmarkTools を使って計算時間などを測定する(記録)
@benchmark で得られる計測値をプログラムで受けたければ
1res = @benchmark Euler_all(u0, 100, 10.0);
2# 最後に ; をつけると結果を画面に出力しない.
のように結果を適当な変数に入力させてから、たとえば
1res.times
とすると、計測した時間(単位は ナノ秒だ)のリストを下記のように得られる.
10000-element Vector{Float64}:
17280.0
17380.0
16640.0
⋮
15440.0
15480.0
15520.0
だから、かかった時間の平均値などは mean( res.times ) とすれば 15561.342 ns = 15.561 μs と得られる.
なお、@benchmark を使ったときに他にどんな情報が得られているかは、複合体変数の構造を見る dump コマンドを使って
dump( res ) とすれば良い.この場合は
BenchmarkTools.Trial
params: BenchmarkTools.Parameters
seconds: Float64 5.0
samples: Int64 10000
evals: Int64 5
evals_set: Bool false
overhead: Float64 0.0
gctrial: Bool true
gcsample: Bool false
time_tolerance: Float64 0.05
memory_tolerance: Float64 0.01
times: Array{Float64}((10000,)) [17280.0, 17380.0, 16640.0, 18360.0, 16600.0, 16700.0, 23760.0, 16760.0, 17160.0, 17380.0 … 15480.0, 15480.0, 15380.0, 15520.0, 15400.0, 15460.0, 15360.0, 15440.0, 15480.0, 15520.0]
gctimes: Array{Float64}((10000,)) [0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0 … 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0]
memory: Int64 11216
allocs: Int64 701
という感じに情報が得られる.
条件を変えて、計算時間(速度)を測る
ではこれで準備ができたので、誤差の評価同様、計算にかかる時間もきちんと評価しよう. 次のようにすればよいはずだ.
1# 全体条件
2T = 10.0 # この時間の…
3
4ratio = 1.5 # 計算回数を毎回 1.5倍する <=> Δt を毎回 2/3 に.
5N_iter = 15 # この試行を何回やるか.
6
7# 初期化
8N = 100
9Δt = T/N
10u0 = 0.1
11
12# 最初に一回計算しておく.
13res = @benchmark Euler_all(u0,N,T);
14cpu_time = mean( res.times ) / 1000 # micro second
15
16println("iter, N, Δt, cpu_time (μs)") # 画面表示
17println("0, $N, $Δt, $cpu_time")
18
19# 記録をとりはじめる.
20sq_dt = [ Δt ]
21sq_cpu_time = [ cpu_time ]
22
23# Δt を小さくしていったときの近似解をそれぞれ求める.
24for i in 1:N_iter
25 N = round(Int, ratio * N) # N を ratio 倍して,
26 Δt = T / N # Δt は 1/ratio 倍になるはず.
27 push!( sq_dt, Δt ) # 記録をとる
28
29 res = @benchmark Euler_all(u0 ,N, T); # 時間を計測
30 cpu_time = mean( res.times )/1000 # micro second
31 push!(sq_cpu_time, cpu_time) # 記録をとる
32
33 println("$i, $N, $Δt, $cpu_time") # 画面表示
34end
こうすると、複数回測定しているため多少時間はかかるが、下記のように $\Delta t$ を変えた場合の計算時間を測定した結果を得られる.
iter, N, Δt, cpu_time
0, 100, 0.1, 15.431516
1, 150, 0.06666666666666667, 20.909869999999998
2, 225, 0.044444444444444446, 35.042019999999994
3, 338, 0.029585798816568046, 45.26758
4, 507, 0.01972386587771203, 69.45419
5, 760, 0.013157894736842105, 115.07205
6, 1140, 0.008771929824561403, 185.31581
7, 1710, 0.005847953216374269, 261.52153
8, 2565, 0.003898635477582846, 404.85833
9, 3848, 0.002598752598752599, 577.3592734004396
10, 5772, 0.0017325017325017325, 869.2212047353761
11, 8658, 0.001155001155001155, 1410.5084180790961
12, 12987, 0.00077000077000077, 1950.5078094494338
13, 19480, 0.000513347022587269, 3221.7510322580647
14, 29220, 0.00034223134839151266, 4975.1046812749
15, 43830, 0.00022815423226100844, 7088.094609929079
これをグラフにして、見てみよう.下記のような感じだろう.
1default( xaxis = ("Δt", :log10),
2 yaxis = ("cpu time (μs)", :log10) )
3
4plot( sq_dt, sq_cpu_time, marker = :circle,
5 label = "Δt vs cpu time for Euler scheme" )
6plot!( sq_dt, sq_dt.^(-1), marker = :none, label = "y = C/x" )
7# 補助線を引いてみる
この両対数グラフでのグラフの傾きは -1 であるし,$y = C/x$ として引いた補助線とも同じ挙動であるので、
Euler 法では $\Delta t$ と計算にかかる時間は反比例する ことがわかる.
計算時間と誤差の関係をみる
さて、Euler 法の持つパラメータ $\Delta t$ と誤差、計算時間との関係はわかったが、 Euler 法を用いる立場からすれば、
Euler法における 計算時間=コスト と 精度=利益 の直接の関係を知っておく
必要がある. どれだけ計算時間をかければどれだけ誤差を小さくできるか、という関係をグラフで見ておけ、ということだ.
今回は既に同じ $\Delta t$ に対する誤差と計算時間の測定をしてあるので、そのデータ をグラフにすれば良い.次のような感じだ.
1default( xaxis = ("cpu time (μs)", :log10),
2 yaxis = ("error", :log10) )
3
4plot( sq_cpu_time, abs.(sq_euler), marker = :circle,
5 label = "cput time vs error by Euler scheme" )
6plot!( sq_cpu_time, 0.03 .* (sq_cpu_time.^(-1)), marker = :none, label = "y = C/x" )
7# 補助線を引いてみる
実用性の点で、これが一番欲しいグラフだ!
この両対数グラフでのグラフの傾きは -1 であるし,$y = C/x$ として引いた補助線とも同じ挙動であるので、
Euler 法では計算にかかる時間と誤差は反比例する ことがわかる.
つまり、誤差を半分にしたければ倍の計算時間を必要とする、ということだ. いずれわかってくるが、これはあまり効率の良い方法とは言えない.もっと良い方法がたくさんあるのだ.
もう少し実用的な問題: 人工衛星の温度変化モデル
|
人工衛星は、太陽光により周期的に暖められつつ、赤外線などで熱を放射して冷える状況にある.これに対するモデル(常微分方程式)を数値計算で見てみよう. |
参考文献
人工衛星の温度変化に関するモデルを提案しているのが下記の論文などだ.
- J. Gaite, A. Sanz-Andrés and I. Pérez-Grande, “Nonlinear analysis of a simple model of temperature evolution in a satellite,” Nonlinear Dynamics, 58, 405–415 (2009). / 上記論文の Arxiv (無料) / の 2page から 3pageあたりに記載.
- N. D. Anh, N. N. Hieu, P. N. Chung and N. T. Anh, “Thermal radiation analysis for small satellites with single-node model using techniques of equivalent linearization,” Applied Thermal Engineering, 94, 607–614 (2016).
モデル方程式
上記の論文などで小型人工衛星の温度 $u(t)$ (ただし $t$ は時間)の変化についてモデル方程式が提唱されている. それに対して太陽光の影響を単純化したものが次の常微分方程式である. \begin{equation} \frac{du}{dt} = 1 + \frac{1}{2} \sin(t) - u^4 . \label{eq:tvmas} \end{equation}
方程式右辺の $1 + (1/2) \sin(t)$ が太陽光による温度上昇のモデルで、 $-u^4$ が赤外線放射などによる温度下降のモデルになる.
この方程式を対象として数値計算してみよう. ただし、$u(t)$ の初期値としては(理由は後述) $(1/2)^{1/4} \leq u(0) \leq ( 3/2 )^{1/4}$ としておく.
方程式の特徴等
この方程式には以下の特徴があるため、授業の対象としてぴったりだ.
- 実際に実用されるモデルである (授業用に少し簡単にしてあるが).
- 変数分離や線形方程式の公式などの「人力で解く手法」が通用しないため、数値計算する必要がある.
- (初期値がその範囲に入っていれば) 解 $u(t)$ は \begin{equation} \left(\frac{1}{2}\right)^{1/4} \leq u(t) \leq \left( \frac{3}{2}\right)^{1/4} \label{eq:range-of-TVMAS} \end{equation} の範囲(数字で書くと、おおよそ $0.84090 \leq u(t) \leq 1.1067$) にその先も収まることがわかるので(レポート課題)、数値解の 検証情報として使える.
- (後でわかるが) 時間刻み幅 $\Delta t$ を荒くすると Euler法が失敗するので数値計算には注意深さzを要する.
Euler 法による離散近似式 (Eulerスキーム)
記号としてはこれまで同様、時間刻みを $\Delta t$ とし、時間 $t_n = n\Delta t$ に対して数値解 $u_n$ は真の解 $u(t_n)$ を近似する、という前提で、モデル方程式 (\ref{eq:tvmas}) に対して Euler法を適用すると以下のような近似式が得られる. \begin{equation} \frac{u_{n+1} - u_n}{\Delta t} = 1 + \frac{1}{2} \sin(n\Delta t) - (u_n)^4 . \end{equation} 左辺に未知数である $u_{n+1}$ をおき、右辺に残りを集めるとこの式は以下のように変形できる. \begin{equation} u_{n+1} = u_n + \Delta t \left( 1 + \frac{1}{2} \sin(n\Delta t) - (u_n)^4 \right). \label{eq:euler-tvmas} \end{equation} これを Euler スキームとして、数値計算に用いよう.
なお、とりあえず最初は $u(t)$ の初期値を $u(0) = 0.9$ としておこう.
Julia の準備は以下のような感じだ.
1# 初期値
2u0 = 0.9
3
4# 数値スキームのパラメータ: 時間刻み幅
5Δt = 0.1 # 特に根拠のない,とりあえずの値.
6
7# Eulerスキーム.
8# 時間に依存する項 sin(t_n = nΔt) があるので、引数に $t_n$ もしくは $n$ が必要.
9Euler(u, n) = u + Δt * ( 1 + sin(n*Δt)/2 - u^4 )
Euler スキームによる数値計算
次のようにプログラムしてこれを動かせばよいだろう.
1u = u0 # 最初の値はもちろん初期値
2u_sq =[ u ] # 結果を記録する
3
4
5for n in 0:99
6 # とりあえずこれぐらい.
7 # 今回は n の値がスキームに影響するので丁寧に考える.最初の値は 0 になる.
8
9 u = Euler(u, n) # 古い u -> 新しい u
10 push!(u_sq, u) # push! で配列に要素を追加.
11end
計算そのものは一瞬で終わるはずだ. 念の為に計算結果の記録を確認しておく.
1u_sq
101-element Vector{Float64}:
0.9
0.93439
0.963153986366745
⋮
0.9835847655623478
0.9716669889600755
0.959650776373918
1using Plots
2
3T = 0:Δt:100Δt # 時間の範囲.最後は u_100 が求まっていることを忘れないこと.
4plot(T, u_sq, marker = :circle, xlabel = "t", ylabel = "u", legend = false )
上の数値計算結果のグラフを見ると、人工衛星の温度 $u(t)$ は周期的な挙動を見せることがわかる. そしてその挙動グラフは、三角関数に似ているが、上部が太く、下部が細くなっており、少し変形していることが読み取れる.
やはり、Euler 法で欲張るとまずいことを確認する
上では Δt = 0.1 として上手く計算できた.これを欲張って Δt = 0.5 としたらどうなるか確認しよう.
下記のようにすればよいだろう.
1Δt = 0.5 # 少し欲張ってみた.
2
3u = u0 # 最初の値はもちろん初期値
4u_sq =[ u ] # 結果を記録する
5
6
7for n in 0:99
8 # とりあえずこれぐらい.
9 # 今回は n の値がスキームに影響するので丁寧に考える.最初の値は 0 になる.
10
11 u = Euler(u, n) # 古い u -> 新しい u
12 push!(u_sq, u) # push! で配列に要素を追加.
13end
計算は無事終了するので、グラフを描いてみよう.
1using Plots
2
3T = 0:Δt:100Δt # 時間の範囲.最後は u_100 が求まっていることを忘れないこと.
4plot(T, u_sq, marker = :circle, xlabel = "t", ylabel = "u", legend = false )
グラフを見ると、$0 \leq t \leq 5$ あたりで、解の範囲の式 (\ref{eq:range-of-TVMAS}) を上下ともに越える値が出現していて、
数値計算としては失敗していることがわかる.
このパラメータについてはあまり欲張らずに、 Δt = 0.1 ぐらいか、より小さくしておくのが良さそうだ.
Euler 法による精度と計算速度
memo: 高精度計算
誤差の挙動を見るために、「真値にかなり近い値」を用意しておきたい. 今回は下記のようにしてみる.プログラムの内容は理解しなくて良い.
1using OrdinaryDiffEqVerner # 手軽に高精度計算をする際にオススメなライブラリらしい.
2
3# 以降、念の為に多倍長計算にしておく.
4f(u, params, t) = BigFloat("1.0") + sin(t)/2 - u^4
5prob = ODEProblem(f, BigFloat("0.9"), ( BigFloat("0.0"), BigFloat("10.0") ))
6
7sol = solve(prob, OrdinaryDiffEqVerner.Vern9();
8 reltol=1e-30, abstol=1e-32) # 30桁ほどの精度を要求しておいて…
9
10sol( BigFloat("10.0") ) # t = 10.0 における近似値
0.9594159419736648864578161172902412227159110145561355413285236447551348045166157
となるので、通常の浮動小数点数に合わせて上から17桁を取得して(最後は四捨五入) \begin{equation} u_{\text{nice}} := 0.9594159419736648865 \end{equation} を真値 $u(10.0)$ に近い値として、誤差の推定の折に使うことにしよう.
真値もどきを得たので
あとは、(上の真値もどきを用いたいので)最終時間を $T = 10.0$ と固定して $\Delta t$ を変えて誤差を測定すればよい(→ レポート課題)
計算時間の測定も
最初の例同様にやってみるだけだ.これも(上の誤差測定と最終的に関係させたいので)最終時間を $T = 10.0$ と固定して$\Delta t$ を変えて計算にかかる時間を測定すれば良い.レポート課題にしておこう.
レポート No.05
以下の課題についてレポートしよう.
ファイル名を 学籍番号-氏名-05.pdf とし,web フォームから提出しよう.
基本的には、ファイルは pdf 形式だ.動画を pdf に埋め込むのは可能だが難しいので、その場合は mp4 などの形式でも良い. 紙媒体で手渡ししても良いが,破損・紛失の可能性があるのでお勧めしない.
一応、レポートやメールには,自分の 所属・学年・学籍番号・氏名 を必ず書いておこう.なにかと安全だ.
課題
-
上の $(\ref{eq:u-min})$ 式の $u_{\mbox{min}}$ の値を自分でも求めてみよう.なお,近似精度はあまり気にしなくて良い.
やり方はいろいろある. 一番オーソドックスなのは式 $(\ref{up:up-u})$ を $u$ で微分した式を手で求めておいて,それがゼロになるところを求める方法だろう.これなら前回までのゼロ点求解の知識が使える.
他には,たとえばx in 2.3:0.01:2.5の範囲で数値的に最小値を探す,なんて強引な方法もあるだろう. いろいろ工夫してみるとよいだろう. -
式 (\ref{eq:range-of-TVMAS}) を導出しよう. そんなに難しくない.
-
人工衛星の温度変化問題に対する Euler 法の精度、計算時間の測定をし、可視化し、関係性を評価しよう.
具体的なやり方は最初の例とほぼ同じで良いので難しくはないだろう. $\Delta t$ を変えつつ誤差と計算時間を測定して、次の3つのグラフを出力し、その評価をすれば良い.
- 横軸 $\Delta t$ vs 縦軸 誤差 のグラフ
- 横軸 $\Delta t$ vs 縦軸 計算時間 のグラフ
- 横軸 計算時間 vs 縦軸 誤差 のグラフ
-
これは教員が動かしたとき,In [29] にこのプログラムを書き込んだからだ. ↩︎
-
一応,
domainerrorについてはマニュアルの Core.DomainError に解説があり,
The argument val to a function or constructor is outside the valid domain.
と書いてある.わかりやすい例も載っている.見ておくと良いね. ↩︎ -
この値は Julia の Optim パッケージを用いて求めた.まあこれはシンプルな問題なので,自分で適当な方法を考えて解いても難しくないはずだ. ↩︎
-
$y = Cx$ という,$y$ と $x$ が比例関係にあるグラフを両対数グラフで描くと,「見かけ上の傾きが 1」の直線になる.ちなみに $y = Cx^2$ のときは傾きが 2 の直線に, $y = Cx^3$ のときは傾きが 3 の直線になる.よくわからない人はちょっと考えてみよう. ↩︎