04. ゼロ点求解法のその他とライブラリ

Photo by Pablo García Saldaña on Unsplash

前回はゼロ点を求めるのに「かなり使える」Newton 法について学んだ. 今回は他の解法を学びつつ,「自分でなんとかするにはどう考えればよいか」という,アルゴリズムの萌芽について少し考えていこう.

そしてその後,ライブラリに頼る方法も学んでおこう. なんといっても通常はライブラリを使ったほうが楽だし,性能も期待できる.

二分法: 実質的に 1次元的な手法で,お気楽

ゼロ点を求める解法として,微分も不要というお気楽な二分法というものがある. これは実質的に関数が $f: \mathbb{R}^1 \rightarrow \mathbb{R}^1$ で連続でないと使えないが、なにしろわかり易いので「近似解を求める方法を作る」考え方を学ぶのには最適な方法の一つだろう.

この二分法も Newton法と同じく近似を少しずつ良くしていく反復解法で,連続な関数 $f: \mathbb{R}^1 \rightarrow \mathbb{R}^1$ に対して適用できる. ただ,Newton法と以下の点が異なる.

  • ゼロ点の近似解そのものを追うのではなく,「ゼロ点を含んでいる区間」を小さくしていく.

  • 「その区間にゼロ点が確実に含まれていること」を, 区間の左端 $x_l$ と右端 $x_r$ に対して \begin{equation} f(x_l) \cdot f(x_r) < 0 \label{a} \end{equation} であることで保証する.

  • 区間の中点で区間を二分して出来た2つの区間のどちらかを新しい区間として採用することで「改善」とする
    ※ このとき,2つの区間のうち,式 $(\ref{a})$ が成り立つ区間を採用する.

この改善プロセスは,
この図でもおおよそわかるだろう. もう少し数式を使って説明すると,次のようになっている.

まず、上記条件下で、 $f(x_{l})$ と $f(x_{r})$ が異符号であることが確認できるような 区間 $\Omega = [x_{l}, x_{r}]$ をなんとか求めることができていると 仮定しよう (初期仮定).

よって,$f(x)$ が連続である(前提)ことから、$\Omega$ の中に少なくとも1つは $f(x) = 0$ を満たす $x$ が存在する.

あとは簡単で、

  1. 区間の真ん中の値 $x_{av} = (x_{l} + x_{r})/2$ に対して $f(x_{av})$ の符号を調べる.

  2. その符号と $f(x_{l})$, $f(x_{r})$ の符号を比較してその結果によって区間を更新する.

    具体的には、$f(x_{l})$ の符号と $f(x_{av})$ の符号が異なるならば区間を $[x_{l}, x_{av}]$ に更新する. 逆に $f(x_{av})$ の符号と $f(x_{l})$ の符号が同じならば区間を $[x_{av}, x_{r}] $ に更新する.

とすれば,区間が更新されるたびに大きさが半分になり,十分に繰り返せば区間が十分小さくなって、しかもその中に解があるはずなのでいつかは満足するよね… というのが二分法だ.

さて、二分法を試してみよう. 例題として、

\begin{equation} \exp(x) = 2 \end{equation}

を満たす $x$ を求めることを考えよう. 解は $\log 2$ なので、最終的に幅が大変に小さくなった範囲がほぼ $\log 2$ そのものであれば OK、ということになる.

まず、$f(x) = 0$ の形に問題を書き直して、

1f(x) = exp(x) - 2.0

次に,初期仮定を満たす $x_{left}, x_{right}$ を用意する.

この場合は、数学の知識を使って $\exp(0) = 1 < 2 < \exp(1) = 2.71828...$ がわかるので、 \begin{equation} f(0) = -1 < 0 < f(1) = 0.71828... \end{equation} ということが言える. つまり,関数 $f$ の値が $x=0$ と $x=1$ で異符号であることになる.

よって最初の区間としては $[0,1]$ を採用することにしよう. プログラムとしては

1left, right = 0.0, 1.0

とでもすれば良いだろう.

一応、念の為に $f(x_{left})$ と $f(x_{right})$ の符号が異なることを確認しておこう.

1f(left)*f(right)
-0.7182818284590451

うん、大丈夫だね.

では早速、二分法でこの区間( 初期は $[0,1]$ということになる )を半分ずつの大きさに小さくしていこう.

 1left, right = 0.0, 1.0 # 最初の区間の左端と右端.
 2
 3sq = [ left right ] # 区間情報を記録しておく.これは横ベクトル.
 4
 5for i in 0:100
 6    av = (left + right)/2 # 区間の真ん中の値
 7
 8    println("$i : $left, $right : $(f(av))") # 状況を画面に
 9
10    if abs(f(av)) < 1.0e-8  # 8桁ぐらい合っていたらループを脱出
11        break
12    end
13
14    if f(left)*f(av) < 0 # f(left)と f(av) が異なる符号ならば
15        right = av # 次の区間は [ left, av ] に.
16    else
17        left = av # そうでなければこちら.
18    end
19    sq = vcat(sq, [ left right ]) # 新しい区間を sq の下に追加.
20end


簡単な解説: yes/no 判定で動作を変える: if文 ← if の簡単な解説
簡単な解説: データ集合の取り扱い ← vcat の簡単な解説

0: 0.0, 1.0: -0.3512787292998718
1: 0.5, 1.0: 0.11700001661267478
2: 0.5, 0.75: -0.13175404256777767
3: 0.625, 0.75: -0.011262530417708083
4: 0.6875, 0.75: 0.05186677348797675
5: 0.6875, 0.71875: 0.020055527708696452
6: 0.6875, 0.703125: 0.004335330874331245
7: 0.6875, 0.6953125: -0.003478832038737778
8: 0.69140625, 0.6953125: 0.0004244339097745353
9: 0.69140625, 0.693359375: -0.0015281520101939616
10: 0.6923828125, 0.693359375: -0.0005520974029782355
11: 0.69287109375, 0.693359375: -6.389134934270402e-5
12: 0.693115234375, 0.693359375: 0.00018025637771179603
13: 0.693115234375, 0.6932373046875: 5.8178788785667734e-5
14: 0.693115234375, 0.69317626953125: -2.8572115997604897e-6
15: 0.693145751953125, 0.69317626953125: 2.7660555759201344e-5
16: 0.693145751953125, 0.6931610107421875: 1.2401613871837469e-5
17: 0.693145751953125, 0.6931533813476562: 4.772186584123261e-6
18: 0.693145751953125, 0.6931495666503906: 9.574838539805341e-7
19: 0.693145751953125, 0.6931476593017578: -9.498647821626349e-7
20: 0.6931467056274414, 0.6931476593017578: 3.809308424251867e-9

ふむ、20回ほど区間を半分にし続けて、最終的にうまくいったようだ.

まず、区間がどうなったか記録を見てみよう.

1sq
21×2 Array{Float64,2}:
0.0       1.0
0.5       1.0
0.5       0.75
0.625     0.75
0.6875    0.75
0.6875    0.71875
0.6875    0.703125
0.6875    0.695313
0.691406  0.695313
0.691406  0.693359
0.692383  0.693359
0.692871  0.693359
0.693115  0.693359
0.693115  0.693237
0.693115  0.693176
0.693146  0.693176
0.693146  0.693161
0.693146  0.693153
0.693146  0.69315
0.693146  0.693148
0.693147  0.693148

そして、これをプロットしてみよう.次のような感じかな. まずいつものように

1using Plots

としてから、

1default(xlabel = "loop number")
2
3hline( [ log(2.0) ], label = "true value", linewidth = 3  )  # hline は水平線を描く
4plot!(sq[:,1], marker = :circle, label = "left boundary")   # 区間の左端の値
5plot!(sq[:,2], marker = :rect,  label =   "right boundary") # 区間の右端の値

とすれば良い.結果が下の図だ.

図. ループが進むたびに区間の幅が半分になっていき、真値に近づく.

このグラフの y軸の値 $[y_1, y_2]$ が更新されていく区間の両端になる. この区間の大きさが毎回「半分」になっていることに注意しよう.

単純なだけに二分法には「改良の余地」がある? 考えてみよう(→ レポートの課題 3).

入力が多次元の場合でも OK

考えている関数 $f$ が連続ならば,入力が多次元値でも二分法は使える. 具体的には,$f: \mathbb{R}^n \rightarrow \mathbb{R}^1$, $n \geq 1$ のケースだ.

なぜ使えるのかは,
上の図をみれば一目瞭然だろう.

要するに,任意の 2点間の線分(曲がっていても良い)の上の関数 $f$ を考えると, 関数 $f$ の連続性によりその線分の上でも関数は連続なので,単純に 1次元のときの問題と同じ状況になるのだ.

だから,「最初に関数 $f$ の値が異符号になるような 2点の $x$ を探すこと」 さえうまくいけばあとは単なる二分法そのものとなる.

入力が2次元の関数のゼロ点を求める例

\begin{equation} f_\text{org}(\boldsymbol{x}) = x^2 + 2y - 2 \end{equation} が $0$ になる点の近似計算をしよう. ただし、$(x,y)=\boldsymbol{x}$ である.

上の考え方に沿うと、この場合の解法は以下の順序になるだろう.

  1. $f_\text{org}(\boldsymbol{x}_\text{left})$ と $f_\text{org}(\boldsymbol{x}_\text{right})$ が異符号になるような 2点 $\boldsymbol{x}_\text{left}$, $\boldsymbol{x}_\text{right}$ を探す.

  2. 2点 $\boldsymbol{x}_\text{left}$, $\boldsymbol{x}_\text{right}$ を線分で繋いて、初期の区間相当にする. 数式で書くならば、$0 \leq t \leq 1$ として、 \begin{equation} \boldsymbol{x}(t) := (1-t) \boldsymbol{x}_\text{left} + t\, \boldsymbol{x}_\text{right} \end{equation} という感じ.
    この場合、初期の区間の 2つの端点は($t$ で見れば) それぞれ $t=0$ と $t=1$ である.

  3. 上の数式により、この線分上の点は $t$ によって $\boldsymbol{x}(t)$ として決まるので、ゼロにすべき関数を \begin{equation} f(t) := f_\text{org}(\boldsymbol{x}(t)) \end{equation} と書くことができる.つまり、対象関数 $f$ の入力が 1次元になって、もとの話に帰着できる.

  4. まとめると、初期端点の左端を $t=0$, 右端を $t=1$ と設定して、上の $f(t)$ に対して二分法を用いれば良い.

実際にやってみよう.順番にやっていくとたとえば次のようになるだろう.

  1. 対象関数が異符号になるような 2つの点を探す.

    1f_org(pt) = pt[1]^2 + 2*pt[2] - 2  # まずは対象関数 f_org を定義する.
    2
    3left_Pt  = [1.1, -1.3] # 適当に勘で決める.
    4right_Pt = [2.0, 3.9]  # こちらも
    5
    6f_org(left_Pt), f_org(right_Pt) # それぞれ、対象関数の値をチェック!
    

    (-3.3899999999999997, 9.8) と出力され、対象関数の値がこの2点で異符号なことが確かめられる.

  2. 2つの点を繋ぐ数式を作る.

    $0 \leq t \leq 1$ として、上で求めた2点の座標を代入して、 \begin{equation} \boldsymbol{x}(t) := (1-t) \boldsymbol{x}_\text{left} + t\, \boldsymbol{x}_\text{right} = \left( {0.9\,t + 1.1}\atop{5.2\,t - 1.3} \right) \label{eq:xt} \end{equation} を得る. プログラムは以下のようになるだろう.

    1x_Pt(t) = (1-t) * left_Pt + t * right_Pt  # 定義通り.展開や計算の必要はない.
    
  3. 入力が1次元の関数へ帰着させる. 数式だと \begin{equation} f(t) = f_\text{org}(\boldsymbol{x}(t)) = f_\text{org}( \left( {0.9\,t + 1.1}\atop{5.2\,t - 1.3} \right) ) = 0.81\,t^2 + 12.38\,t - 3.39 \end{equation} と計算できる. プログラムは以下のようになるだろう.

    1f(t) = f_org(x_Pt(t))  # これも定義通り.展開や計算の必要はない.
    
  4. あとは、$t=0$, $t=1$ を初期区間の端点として、上の $f(t)$ に対して二分法を行えば良い. プログラムは1次元の時のものそのままが使える.下記のようになる(まったく同じプログラム).

     1left, right = 0.0, 1.0 # 最初の区間の左端と右端.
     2
     3sq = [ left right ] # 区間情報を記録しておく.これは横ベクトル.
     4
     5for i in 0:100
     6    av = (left + right)/2 # 区間の真ん中の値
     7
     8    println("$i : $left, $right : $(f(av))") # 状況を画面に
     9
    10    if abs(f(av)) < 1.0e-8  # 8桁ぐらい合っていたらループを脱出
    11        break
    12    end
    13
    14    if f(left)*f(av) < 0 # f(left)と f(av) が異なる符号ならば
    15        right = av # 次の区間は [ left, av ] に.
    16    else
    17        left = av # そうでなければこちら.
    18    end
    19    sq = vcat(sq, [ left right ]) # 新しい区間を sq の下に追加.
    20end
    

    実行すると、下記のような出力になるはずだ.

     0 : 0.0, 1.0 : 3.0024999999999995
     1 : 0.0, 0.5 : -0.2443749999999998
     2 : 0.25, 0.5 : 1.3664062499999998
     3 : 0.25, 0.375 : 0.5578515625000002
     4 : 0.25, 0.3125 : 0.1559472656249996
     5 : 0.25, 0.28125 : -0.044411621093749964
     6 : 0.265625, 0.28125 : 0.055718383789062464
     7 : 0.265625, 0.2734375 : 0.0056410217285156605
     8 : 0.265625, 0.26953125 : -0.01938838958740252
     9 : 0.267578125, 0.26953125 : -0.006874456405639551
     10 : 0.2685546875, 0.26953125 : -0.0006169104576114748
     11 : 0.26904296875, 0.26953125 : 0.0025120073556896827
     12 : 0.26904296875, 0.269287109375 : 0.0009475363790989455
     13 : 0.26904296875, 0.2691650390625 : 0.00016530994325858472
     14 : 0.26904296875, 0.26910400390625 : -0.0002258010115472331
     15 : 0.269073486328125, 0.26910400390625 : -3.0245722737021197e-5
     16 : 0.2690887451171875, 0.26910400390625 : 6.753206311227444e-5
     17 : 0.2690887451171875, 0.26909637451171875 : 1.8643158401054905e-5
     18 : 0.2690887451171875, 0.2690925598144531 : -5.801285115403232e-6
     19 : 0.2690906524658203, 0.2690925598144531 : 6.420935906081837e-6
     20 : 0.2690906524658203, 0.2690916061401367 : 3.0982521170841437e-7
     21 : 0.2690906524658203, 0.2690911293029785 : -2.7457299980326866e-6
     22 : 0.2690908908843994, 0.2690911293029785 : -1.2179524047084556e-6
     23 : 0.26909101009368896, 0.2690911293029785 : -4.5406359938660046e-7
     24 : 0.26909106969833374, 0.2690911293029785 : -7.211919506033837e-8
     25 : 0.26909109950065613, 0.2690911293029785 : 1.1885300787994879e-7
     26 : 0.26909109950065613, 0.2690911144018173 : 2.3366906631849815e-8
     27 : 0.26909109950065613, 0.2690911069512367 : -2.4376144214244277e-8
     28 : 0.2690911032259464, 0.2690911069512367 : -5.04619013241836e-10
    

    最後の出力が近似値を出力していることを確認しよう.まず、

    1sq[end,:]
    

    とすると改善された $t$ の区間の最後のものが

     2-element Vector{Float64}:
      0.2690911032259464
      0.2690911069512367
    

    と出力される. そこで $t$ の近似値としてこの平均を取って

    1t_approx = sum(sq[end,:])/2
    

    としておこう.値は 0.2690911050885916 となる.

    1f( t_approx )
    

    とすると

     -5.04619013241836e-10
    

    となり、確かにこの $t_\text{approx}$ が($t$ でみたときの)ゼロ点の近似値として成り立ちそうだ.

    あとは、もとの問題に合わせて式 (\ref{eq:xt}) を用いて 2次元での値に翻訳するには下記のようにすれば良い.

    1x_Pt(t_approx)
    

    すると

     2-element Vector{Float64}:
      1.3421819945797324
      0.0992737464606761
    

    となるので、もとの問題のゼロ点の近似として \begin{equation} \boldsymbol{x}_\text{approx} = \left( {1.3421819945797324}\atop{0.0992737464606761} \right) \end{equation} を得られる.

等高線グラフで納得してみる

上の二分法の端点の変化を,等高線グラフを描くことで納得してみよう. まずは $f_\text{org}()$ の等高線をグラフにする.

1using Plots
2
3Rx = 0.9:0.05:2.2
4Ry = -1.5:0.05:4.1
5
6Z = [ f_org([x,y]) for x in Rx, y in Ry ]
7
8contour( Rx, Ry, Z', fill = true, xlabel = "x", ylabel = "y" )

次に、二分法で小さくなっていく区間の両端相当の点をグラフにしてみる.

1X = sq[:, 1] # t でみる区間の左端のリスト
2Y = sq[:, 2] # t でみる区間の右端のリスト
3
4left_Pts  = x_Pt.(X) # 左端相当の 2次元の点のリストに変換(というか戻すというべきか)
5right_Pts = x_Pt.(Y) # 同上(右端)
6
7# とりあえず plot してみる.
8scatter( Tuple.(left_Pts) )   # 区間の左端相当の点をプロット
9scatter!( Tuple.(right_Pts) ) # 区間の右相当の点を(追加で)プロット
図.青い点が区間の左端相当の点で、オレンジの点が右端相当.

そしてこれらを、下記のようにして先の等高線に重ねてみよう.わかりやすいようにいろいろ表示を工夫してみる.

1contour( Rx, Ry, Z', fill = true, xlabel = "x", ylabel = "y", legend = false, colorbar = true )
2
3scatter!( (1.342, 0.09927), color = :greenyellow, marker = :hexagon, markersize = 20 )
4scatter!( Tuple.(left_Pts), st = :path, color = :cyan, marker = :rect, markersize = range(3,7; length = length(left_Pts)) )
5scatter!( Tuple.(right_Pts), st = :path, color = :white, marker = :circle, markersize = range(3,7; length = length(right_Pts)) )
図.青い四角い点が区間の左端相当の点で、白い丸い点が右端相当.計算ループが進むにつれて点の大きさが大きくなるように表示している. 最終的な近似点 $(1.34..., 0.0992...)$ (緑色の六角形)に近づいていることが見て取れる.

ライブラリ NLsolve に頼ってみよう

自分で組んだ Newton 法や二分法等のルーチンがうまくうごかないような問題もあるだろう. それに、例えば Newton 法は微分関数を計算して求めておく必要があるし,二分法は1次元問題しか解けない. 他の解法もそれぞれに欠点がある.

そこで、自作プログラムだけでなく,ケースバイケースで判断してくれる,ほぼ半自動の既存のライブラリを使えるようになっておこう.

今回は、NLsolve という、非線形方程式の近似根を求めるそのものズバリのライブラリ(Package)を使ってみよう.

パッケージの使い方

あらためて Julia のパッケージとはなにか、について話しておこう. julia には, 公開・配布されているライブラリがたくさんあり、これらがパッケージ(package)と呼ばれている.

ちなみに,Julia のパッケージリストは JuliaHub や Julia packages などで見られる. 前者は網羅的な情報が,後者は今の流行りの情報が見られる感じの web だ.

さて、こうしたパッケージの使い方はシンプルで、インストールして、あとは使うたびに呼び出すというだけだ. ここでは、NLsolve パッケージを例にして説明しよう.

インストール

まずは NLsolve package をインストールしよう. Plots などと同様に、以下のように一回だけやれば良い.

1using Pkg
2Pkg.add("NLsolve")

パッケージの呼び出し

これも Plots などと同様に、NLsolve を使いたい時は

using パッケージ名

とすれば良い. というわけで、今回の授業ではまず (NLsolve のインストールを済ませてから) 次のようにして使用宣言を今しておこう.

1using NLsolve

NLsolve パッケージの使い方

このパッケージは非線形問題の汎用解法ライブラリなので、そのままだとちょっと使いにくい. ここでは処方箋だけ書いておこう.


NLsolve: 非線形方程式の求根 package ← NLsolve について書いた(古い)解説

この処方箋とは、using NLsolve のあとに、続けて nls という関数を julia で定義しておいて、あとはこの関数 nls を使うという手である. このためには、この関数を定義しておかないといけないので、やっておこう.次のようになる.

 1function nls(func, params...; ini = [0.0])
 2    if typeof(ini) <: Number
 3        r = nlsolve((vout,vin)->vout[1]=func(vin[1],params...), [ini])
 4        v = r.zero[1]
 5    else
 6        r = nlsolve((vout,vin)->vout .= func(vin,params...), ini)
 7        v = r.zero
 8    end
 9    return v, r.f_converged
10end

定義した関数 nls の使い方

スカラー問題と、ベクトル問題で分けて解説しておこう.

スカラー問題の場合

解きたい方程式が, スカラー変数 $x$ に対してスカラー値関数 $f$ を用いて $f(x,params)=0$ ($params$ はパラメータ, つまり、関数 $f$ の2つ目以降の引数) となっている場合は、

nls( f, params, ini = xの初期値 )

とすれば近似根を取り出せる. 文法的に、初期値設定 ini = は省略できないが、params はあってもなくても複数でも良い.

ベクトル問題の場合

解きたい方程式が, ベクトル値変数 $\boldsymbol{x}$ に対してベクトル値関数 $\boldsymbol{f}$ を用いて $\boldsymbol{f}(\boldsymbol{x}, params) = \boldsymbol{0}$ (params はパラメータ、つまり、関数 $f$ の2つ目以降の引数) となっている場合は、

nls( f, params, ini = xの初期ベクトル )

とすれば近似根ベクトルを取り出せる. 文法的に、初期値設定 ini = は省略できないが、params はあってもなくても複数でも良い.

スカラー問題をやってみる

パラメータがない、とても簡単な例をやってみよう. $\cos$ 関数の根、つまり、$\cos(x) = 1 / 7$ を満たす $x$ を一つ求めてみよう. それには、例えば近似根の初期値を $1.0$ などとして次のようにすれば良い.

1f(x) = cos(x) - 1/7
2sol = nls(f, ini = 1.0)  # ini = 1.0 は近似根 x の探索初期値.
(1.4274487588352782, true)

すると上のように出力され、一つ目の数字が近似根で、2つめの "true" が「この近似根で $f \cong 0$ となっている」ことが確かめられる.

一応、近似根がうまく求まっていることを確認しておこう.

1x = sol[1]  # 並んでいるデータの一つ目を取り出す.
2f(x)  # そして、f に代入して、ゼロに近いかどうかを見てみる.
-9.360467123631366e-10

結果は 0 に大変近い.確かに、この近似根は十分「良い」と言って良さそうだ.

ベクトルや集合 $v$ の第 $k$ 要素は、v[k] として表される.

次に、パラメータ(関数 $f$ の2つ目以降の引数のこと)が有る例をやってみよう. 例として、パラメータ $p$ の平方根を求めるような問題を考えてみよう. それには、 関数を $f(x,p) = x^2 - p$ としてこの根 $x$ を求めればいい. だから、次のようになるだろう.

1f(x,p) = x^2 - p
2nls(f, 2.0, ini=1.0) # 二つ目の引数 2.0 はパラメータ
(1.4142135623746899, true)

すると確かに $\sqrt{2}$ 相当が得られている.

パラメータは複数でも良いので、それを例でみてみよう. 例えば、上の関数を少しだけいじって $f(x,p,q) = x^q - p$ としてこの根 $x$ を求める問題を考えよう.

1f(x,p,q) = x^q - p
2
3sol = nls(f, 2.0, 2.1, ini=1.0) 
4# x^(2.1) - 2.0 = 0 の近似根を求める
(1.391065619249075, true)

この値が確かに近似根になっていることは、結果の "true" 部分からも分かるが、確かめてみると、

1sol[1]^(2.1) - 2.0
9.798828415341632e-12

となるので、確認できる.

さて、近似根がうまく求まらない「はず」な問題も念のために扱ってみよう. 単純なケースとして、負の数字の平方根を求めることに相当する近似根計算をさせてみよう.

1f(x,p) = x^2 - p
2nls(f, -0.0001, ini = 1.0)  
3# x^2 = - 0.0001 を解こうとしているが、当然、実数解は存在しない…
(-4.385150007238086e-11, false)

出力をみると、(探索ルーチンが頑張って求めた)一見近似根っぽい数字が一つ目の出力項に出ているけれども、2つめの出力項が false となっている.

これは 近似解を求めることに失敗した! と言っている のである.

「ややこしい関数で近似根を求めさせると失敗するかも」というようなケースでは、この「計算に成功したかどうか」をきちんとチェックするようにプログラムを書いたほうが良さそうだ.

ベクトル値問題もやってみよう

入出力値がベクトルの問題もやってみよう. まずは前回(Newton法の回)で扱った連立非線形方程式問題に取り組んでみよう.

まず、対象となる関数を以前とまったく同じく定義して…

1function f(vx)
2    x, y = vx
3    return [
4        x+2y+1
5        x^2+2y^2-1
6    ]
7end

で、適当な初期値をいれて関数 nls で解を求めてもらおう.

1nls(f, ini = [1.0, 0.0])
([0.3333333341166318, -0.6666666670583159], true)

… いやあ、これは簡単だ. Newton 法のときは Jacobi行列を計算した上にプログラムしないといけなかったが、NLsolve を使っている限りそんな手間も不要だ. 大変に楽だな.

次に、パラメータを持つ問題を扱ってみよう. 例えば パラメータ $p,q$ に対して,

\begin{equation} \left\{\begin{array}{rcl} \cos^2(x) + \sin^2(y) & = & p, \cr \sin^2(x) - \cos^2(y) & = & q \end{array}\right. \end{equation}

という連立方程式を満たす近似根 $x,y$ が欲しいとしよう.

まず,この問題に対して等価な $h(\boldsymbol{x}, p, q) = \boldsymbol{0}$ という式を満たすように関数 $h$ を次のように定義しよう.

1function h(u, p, q) 
2    a,b = u
3    return [ cos(a)^2 + sin(b)^2 - p, sin(a)^2 - cos(b)^2 - q ]
4end 

試しに,適当な値を入れてこの関数が動作するかどうかチェックしてみる.

1h([4.0,4.0], 0.5, 0.4)
2-element Array{Float64,1}:
0.5
-0.2544999661913866

確かに、ベクトル値が出力され、動作はきちんとしていそうだ.

では,上のご託宣に従って,近似根を求めてみよう.

1p = 0.5
2q = 0.4
3ini_v = [4.0,4.0]
4
5sol = nls(h, p, q, ini = ini_v) # パラメータが複数でも大丈夫.
([4.486875574486246, 3.8769071064064615], true)

true と出ているので大丈夫なはずだが、この値が近似根になっていることを確認しておこう.

1h(sol[1], p, q)
2-element Array{Float64,1}:
 1.3633538742396922e-13
-1.3666845433135677e-13

確かにほぼ ゼロベクトルが出力されるので、OK と言って良さそうだ.

レポート No.04

以下の課題についてレポートしよう. ファイル名を 学籍番号-氏名-04.pdf とし,web フォームから提出しよう.

基本的には、ファイルは pdf 形式だ.動画を pdf に埋め込むのは可能だが難しいので、その場合は mp4 などの形式でも良い. 紙媒体で手渡ししても良いが,破損・紛失の可能性があるのでお勧めしない.

  一応、レポートやメールには,自分の 所属・学年・学籍番号・氏名 を必ず書いておこう.なにかと安全だ.

課題

  1. 自分で $\sin(x) = 3 / 4$ の近似解を求めてみよう. 具体的には,
  • 二分法を用いて自分でプログラムして近似解を求める

  • NLsolve パッケージを使って近似解を求める

    の両方をやろう.ほぼ即座にできるだろう.

  1. 非線形連立方程式の近似解も求めてみよう.
    具体的には, \begin{equation} \left\{\begin{array}{rcl} x + 2y + z & = & -1, \cr x^2 + 2y^2 + z^2 & = & 10, \cr \sin(x+y+z) & = & 0.7 \end{array}\right. \end{equation} の近似解を,
  • NLsolve を使って

  • Newton 法で自力でプログラムして、

    の両方で求めてみよう.

  1. (チャレンジ課題) 自分で解法を考えよう
    例えば $\sin(x) = 3 / 4$ の近似解を求める解法を「自分で創って」みよう.そして実際にプログラムをして動かして試してみよう. なお,まったく新しい解法でなく,Newton 法や二分法の改良でも良い.